home *** CD-ROM | disk | FTP | other *** search
/ 8bitfiles.net/archives / archives.tar / archives / compuserve-file-archive / 22 Graphics & Utilities / DVIEW.BIN (.txt) < prev    next >
Encoding:
Commodore BASIC  |  2019-04-13  |  1.4 KB  |  30 lines
  1. 10 PRINTCHR$(14)"ô─╧╧─╠┼! ╓IEWER"
  2. 20 REM CHR$(14) KICKS IN UPPER/LOWER CASE
  3. 30 PRINT"BY"
  4. 40 PRINT"╙TEPHEN ╨. ╬YE"
  5. 50 A=780:X=781:Y=782:REM .A .X & .Y REG FOR SYS CALLS
  6. 60 FI$="":REM CLEAR OLD FILENAME FOR SECOND LOAD
  7. 70 PRINT"┼NTER A BLANK FILENAME TO END."
  8. 80 PRINT"";:INPUT"╞ILENAME TO LOAD";FI$
  9. 90 IFFI$=""THEN END:REM END OF PROGRAM HERE
  10. 100 PRINT"╘APE USERS ENTER A 1."
  11. 110 INPUT"╞ILES ON DRIVE (8/9)";D0
  12. 120 IF(D0<>1)AND(D0<>9)THEND0=8:REM DRIVE 8 FOR DEFAULT
  13. 130 PRINT"ô":FOR T=1 TO LEN(FI$):POKE49152+T,ASC(MID$(FI$,T,1)):NEXT
  14. 140 REM PUT FILENAME WHERE THE KERNAL CAN FIND IT
  15. 150 POKE49152,LEN(FI$):REM PUT FILENAME LENGTH WHERE KERNAL CAN FIND IT
  16. 160 POKE53272,PEEK(53272)OR8:REM PUT HIRES MAP AT $2000
  17. 170 POKE53265,PEEK(53265)OR32:REM KICK INTO HIRES MODE
  18. 180 POKEA,1:POKEX,D0:POKEY,0:SYS65466
  19. 190 REM LDA #1 - LDX #DRIVE NUMBER - LDY #0 (RELOCATED LOAD) - JSR SETLFS
  20. 200 POKEA,LEN(FI$):POKEX,01:POKEY,192:SYS65469
  21. 210 REM LDA #(LEN FILENAME) - LDX #<$C001 - LDY #> $C001 - JSR SETNAM
  22. 220 REM FILENAME IS LOCATED AT $C001
  23. 230 POKEA,0:POKEX,0:POKEY,28:SYS65493
  24. 240 REM POKE Y,32 FOR RAW (8K) HIRES DATA FILES
  25. 250 REM LDA #0 (RELOCATED LOAD) - LDX #$00 - LDY #$1 - JSR LOAD
  26. 260 GETA$:IFA$=""THEN260:REM SIT AND LOOK AT THE PRETTY P    
  27. 270 POKE53272,PEEK(53272)AND(255-8):REM RETURN TO NORMAL VIDEO MAP
  28. 280 POKE53265,PEEK(53265)AND(255-32):REM RETURN TO NORMAL VIDEO MODE
  29. 290 GOTO60
  30.